PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49

# Maintainer: Chris Tam <LChris314 at gmail dot com>

_pkgname=Overmix
pkgname=overmix
_pkgver=0.4.0-alpha3
pkgver="${_pkgver/-/}"
pkgrel=2
pkgdesc='Automatic anime screenshot stitching in high quality'
arch=('x86_64')
url='https://github.com/spillerrec/Overmix'
license=('GPL3')
depends=(
  'qt5-base'
  'qt5-x11extras'
  'ffmpeg'
  'zlib'
  'xz'
  'libpng'
  'libjpeg'
  'libraw'
  'fftw'
  'pugixml'
  'lcms2'
  'eigen'
  'qcustomplot'
  'libxcb'
)
makedepends=('cmake' 'boost' 'png++')

source=("https://github.com/spillerrec/Overmix/archive/refs/tags/v${_pkgver}.tar.gz")
sha256sums=('759e1b32d2c95e0b5ff6b3b938034d25ac54dea65a84deffd88d533056378b25')

prepare() {
    sed -i -E 's/^#include\s+<exception>$/&\n#include <stdexcept>/' "${_pkgname}-${_pkgver}/src/containers/DelegatedContainer.hpp"
    cmake \
        -B build \
        -S "${_pkgname}-${_pkgver}" \
        -DCMAKE_BUILD_TYPE=Release \
        -DCMAKE_INSTALL_PREFIX=/usr
}

build() {
    make -C build
}

package() {
    make -C build DESTDIR="$pkgdir" install
    install -Dm644 "${_pkgname}-${_pkgver}/license.txt" -t "${pkgdir}/usr/share/licenses/${pkgname}"
}