blob: 825c8a6de6bf2fc05b96e02e01577ba082c368a2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
# Maintainer: Konstantin Shalygin <k0ste@k0ste.ru>
# Contributor: Konstantin Shalygin <k0ste@k0ste.ru>
pkgname='ovirt-guest-agent'
_mainver='1.0.12'
_subrel='2'
pkgver="${_mainver}.${_subrel}"
pkgrel='1'
pkgdesc='The oVirt Guest Agent'
arch=('x86_64')
url="http://ovirt.org/develop/developer-guide/vdsm/guest-agent"
depends=('systemd' 'python2' 'python2-dbus' 'python2-gobject2' 'dbus-glib' 'python2-ethtool' 'usermode')
makedepends=('pam' 'libtool' 'python2' 'python2-pycodestyle' 'patch' 'autoconf')
license=('ASL 2.0')
install="${pkgname}.install"
source=("https://evilissimo.fedorapeople.org/releases/${pkgname}/${_mainver}/${pkgname}-${pkgver}.tar.bz2"
"python2-arch.patch"
"ovirt-guest-agent-1.0.12.1_python_pycodestyle.patch"
"sysusers.conf"
"${pkgname}.service")
sha256sums=('8bf256b95907c5a1ddfd566a3b5c08d46343f6b47dfd9ad99f7c9408e47363e9'
'95c162b584dd137296bcec70d14079d4b93d10d8542a87bd8f1cd6ad01e4b140'
'23ca1080d0ea1c4214afa60849087c91e8eaecf03afcb69ef9ee19220644163a'
'fab3d62ecd8f6546d5b193f4ca22919de20451678b4cce2c53aa0977fed4f483'
'545235630d6da51b547c1e8c177ddbf9f57aa81017b8683274a449d46e765cc4')
backup=("etc/${pkgname}.conf")
prepare() {
cd "${srcdir}/${pkgname}-${pkgver}"
patch -p1 -i "${srcdir}/python2-arch.patch"
patch -p1 -i "${srcdir}/ovirt-guest-agent-1.0.12.1_python_pycodestyle.patch"
autoreconf -i
PYTHON=/usr/bin/python2 ./configure \
--prefix=/usr \
--bindir=/usr/bin \
--sbindir=/usr/bin \
--sysconfdir=/etc \
--localstatedir=/var \
--libdir=/usr/lib \
--datarootdir=/usr/share \
--datadir=/usr/share \
--infodir=/usr/share/info \
--includedir=/usr/include/security \
--with-systemdsystemunitdir=/usr/lib/systemd/system \
--with-pam-prefix=/etc \
--without-gdm \
--without-kdm \
--enable-securedir=/usr/lib/security
}
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
libtool --finish ${pkgdir}/usr/lib/security
install -Dm644 "${srcdir}/${pkgname}.service" "${pkgdir}/usr/lib/systemd/system/${pkgname}.service"
install -Dm644 "${srcdir}/sysusers.conf" "${pkgdir}/usr/lib/sysusers.d/${pkgname}.conf"
install -dm775 -o 175 -g 175 "${pkgdir}/var/log/${pkgname}"
}
|