blob: 8a2ac0f7170f1ec395ca3de2b5c0706881c1d0ba (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer: Martins Mozeiko <martins.mozeiko@gmail.com>
pkgname=ownfoil-git
pkgver=r375.13da9c3
pkgrel=2
pkgdesc='Switch library manager, with a self-hosted Tinfoil Shop'
arch=('any')
url='https://github.com/a1ex4/ownfoil'
license=('custom')
provides=('ownfoil')
conflicts=('ownfoil')
depends=(
'python'
'python-croniter'
'python-flask'
'python-flask-login'
'python-flask-migrate'
'python-flask-sqlalchemy'
'python-yaml'
'python-requests'
'python-unzip-http'
'python-watchdog'
'python-werkzeug'
'python-zstandard'
'nsz-git' # git version because #217 pull request is important
# latest 4.6.1 release does not include it
)
source=("git+https://github.com/a1ex4/ownfoil"
'ownfoil.service'
'ownfoil.sysusers'
'ownfoil.tmpfiles'
)
sha256sums=('SKIP'
'528de3cc691edb57a44e512024832a1a1d0947dbbcda84e487b033150edc6193'
'aee7a6c72d655e29365fe266165ffb714666507a9536871500ced59e0f5d992f'
'abe899a8eecb080f3b938c2441e09838a539f6bfc00e8207ade74bb18c1a5a12')
pkgver()
{
cd ownfoil
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
package()
{
install -m0755 -d "${pkgdir}/usr/lib/ownfoil"
cp -dr --no-preserve='ownership' "${srcdir}/ownfoil/app/." "${pkgdir}/usr/lib/ownfoil"
ln -s "/var/lib/ownfoil" "${pkgdir}/usr/lib/ownfoil/config"
ln -s "/var/lib/ownfoil" "${pkgdir}/usr/lib/ownfoil/data"
install -Dm0644 "${srcdir}/ownfoil.sysusers" "${pkgdir}/usr/lib/sysusers.d/ownfoil.conf"
install -Dm0644 "${srcdir}/ownfoil.tmpfiles" "${pkgdir}/usr/lib/tmpfiles.d/ownfoil.conf"
install -Dm0644 "${srcdir}/ownfoil.service" "${pkgdir}/usr/lib/systemd/system/ownfoil.service"
}
|