blob: 4b6958048abffca1696e33adae333d90f1758da5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: AlphaLynx <alphalynx at alphalynx dot dev>
pkgname=oxicord-git
pkgver=0.1.9.r8.gb65b93b
pkgrel=1
pkgdesc='Vim-native Discord TUI for terminal enthusiasts'
arch=(x86_64)
url='https://github.com/linuxmobile/oxicord'
license=(GPL-3.0-only)
depends=(chafa dbus glibc libgcc)
makedepends=(cargo git)
provides=(oxicord)
conflicts=(oxicord)
options=(!lto)
source=("git+$url.git")
b2sums=('SKIP')
pkgver() {
cd oxicord
git describe --long --tags --abbrev=7 | sed 's/^v//;s/-/.r/;s/-/./'
}
prepare() {
cd oxicord
export RUSTUP_TOOLCHAIN=stable
cargo fetch --locked --target host-tuple
}
build() {
cd oxicord
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
export CARGO_PROFILE_RELEASE_DEBUG=true
export CARGO_PROFILE_RELEASE_STRIP=none
cargo build --frozen --release --all-features
}
check() {
cd oxicord
export RUSTUP_TOOLCHAIN=stable
cargo test --frozen --all-features
}
package() {
cd oxicord
install -Dm755 target/release/oxicord -t "$pkgdir/usr/bin"
}
|