blob: 924697b8490371fd12049b96d1da99d436a18c6a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
|
# Maintainer: Brian Bidulock <bidulock@openss7.org>
# Contributor: gls <ghostlovescorebg at gmail dot com>
# Contributor: Thermi <noel at familie-kuntze dot de>
# Contributor: Tim Meusel <tim@bastelfreak.de>
pkgname=pacemaker
pkgver=1.1.18
pkgrel=4
pkgdesc="advanced, scalable high-availability cluster resource manager"
arch=('i686' 'x86_64')
url="https://github.com/ClusterLabs/${pkgname}/"
license=('GPL2')
makedepends=('inkscape' 'help2man' 'asciidoc')
depends=('gnutls' 'glib2' 'pam' 'libtool' 'python-lxml' 'python-yaml' 'libesmtp'
'corosync' 'libqb' 'resource-agents' 'fence-agents'
'ha-glue' 'net-snmp')
optdepends=('pssh: for use with some tools'
'pdsh: for use with some tools'
'crmsh: for use with crm_report')
install=${pkgname}.install
source=("https://github.com/ClusterLabs/$pkgname/archive/Pacemaker-$pkgver.tar.gz"
'crm_report.in')
sha512sums=('63c287888e5f0bd5f1a2f56450cb3d4da580df2d750ffa90b2212a4efcfa146e05e258a9d87fdcaacde5f8985b9730dae11c5d5ad22e811fd114e1640365c9aa'
'09a80f5579db9016dcbba759ee9b661aea24ed7c98906939d5e50befb344c693652a9634ab804a91bfedeeeb69ce5ab87f30d2ed356bfefd9cdc67669a1cce64')
prepare() {
cd ${pkgname}-Pacemaker-${pkgver}
autoreconf -fiv
# ./autogen.sh
}
build() {
cd ${pkgname}-Pacemaker-${pkgver}
./configure \
CPPFLAGS= \
--sbindir=/usr/bin \
--sysconfdir=/etc \
--libdir=/usr/lib \
--libexecdir=/usr/lib \
--localstatedir=/var \
--disable-static \
--disable-fatal-warnings \
--with-version=$pkgver-$pkgrel \
--enable-systemd \
--disable-upstart \
--with-ais \
--with-corosync \
--without-heartbeat \
--without-cman \
--with-cs-quorum \
--with-nagios \
--with-snmp \
--with-esmtp \
--with-acl \
--with-cibsecrets \
--without-profiling \
--without-coverage \
--with-configdir=/etc/pacemaker
# --with-nagios-plugin-dir=DIR
# --with-nagios-metadata-dir=DIR
make V=0
}
package() {
cd ${pkgname}-Pacemaker-${pkgver}
make DESTDIR="${pkgdir}" install
cd "$srcdir"
install -Dm644 /dev/null "$pkgdir/usr/lib/tmpfiles.d/$pkgname.conf"
cat>"$pkgdir/usr/lib/tmpfiles.d/$pkgname.conf"<<-EOF
d /var/log/pacemaker 0755 hacluster haclient
d /var/lib/pacemaker 0770 hacluster haclient
d /var/lib/pacemaker/blackbox 0770 hacluster haclient
d /var/lib/pacemaker/cib 0770 hacluster haclient
d /var/lib/pacemaker/cores 0770 hacluster haclient
d /var/lib/pacemaker/pengine 0770 hacluster haclient
EOF
# install -Dm644 /dev/null "$pkgdir/usr/lib/sysusers.d/$pkgname.conf"
# cat>"$pkgdir/usr/lib/sysusers.d/$pkgname.conf"<<-EOF
# u hacluster 189 "Cluster User"
# g haclient 189 -
# m hacluster haclient
# EOF
rm -fr "$pkgdir/var"
chmod a+x "$pkgdir/usr/share/pacemaker/tests/cts/CTSlab.py"
find "$pkgdir" -name '*.xml' -type f -print0 | xargs -0 chmod a-x
find "$pkgdir" -type f -name '*.la' -delete -print
rm -fr "$pkgdir/etc/init.d"
rm -f "$pkgdir/usr/bin/fence_pcmk"
mv "$pkgdir/usr/bin/crm_report" "$pkgdir/usr/bin/crm_report.pacemaker"
install -Dm755 crm_report.in "$pkgdir/usr/bin/crm_report"
}
# vim: set sw=2 et ts=2:
|