summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 8c5d4e347adc70b81bd515f2ebf8b369619387a1 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
# Maintainer: Daniel M. Capella <polyzen@archlinux.org>
# Maintainer: Johannes Löthberg <johannes@kyriasis.com>

_gitname=pacman-contrib
pkgname=pacman-contrib-git
pkgver=1.2.0.r9.g3da550e
pkgrel=1
pkgdesc='Contributed scripts and tools for pacman systems'
url=https://git.archlinux.org/pacman-contrib.git/about/
arch=('x86_64')
license=('GPL')
depends=('fakeroot' 'pacman' 'perl')
makedepends=('asciidoc' 'git')
optdepends=('findutils: pacdiff'
            'mlocate: pacdiff'
            'sudo: privilege elevation for several scripts')
provides=("$_gitname")
conflicts=("$_gitname")
source=('git+https://git.archlinux.org/pacman-contrib.git')
sha512sums=('SKIP')

pkgver() {
  cd $_gitname
  git describe --long --tags | sed -r 's/^v//;s/-/.r/;s/-/./'
}

prepare() {
  cd $_gitname
  ./autogen.sh
}

build() {
  cd $_gitname
  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --localstatedir=/var \
    --enable-git-version
  make
}

check() {
  make -C $_gitname check
}

package() {
  cd $_gitname
  make DESTDIR="$pkgdir" install
}

# vim:set ts=2 sw=2 et: