PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34

# Maintainer: Jerry <isjerryxiao at outlook dot com>
_srcname=pacroller
pkgname=pacroller-dev-git
pkgver=0.1.7.13.g5792891
pkgrel=1
pkgdesc="Unattended upgrade for archlinux"
arch=('any')
url="https://github.com/isjerryxiao/pacroller"
license=('GPL3')
depends=('python')
makedepends=('python-setuptools' 'git')
optdepends=('needrestart')
provides=("pacroller")
conflicts=("pacroller")
backup=('etc/pacroller/config.json' 'etc/pacroller/smtp.json' 'etc/pacroller/telegram.json' 'etc/pacroller/known_output_override.py')
source=("$_srcname::git+https://github.com/isjerryxiao/pacroller.git#branch=dev")
md5sums=('SKIP')

pkgver() {
    cd "$srcdir/$_srcname"
    git describe --tags --long | sed 's/^v//;s/-/./g'
}

package() {
    cd "$srcdir/$_srcname"
    python setup.py install --root="$pkgdir/" --optimize=1
    install -Dm644 "src/$_srcname/config.json" "$pkgdir/etc/pacroller/config.json"
    install -Dm600 "src/$_srcname/smtp.json" "$pkgdir/etc/pacroller/smtp.json"
    install -Dm600 "src/$_srcname/telegram.json" "$pkgdir/etc/pacroller/telegram.json"
    install -Dm644 "src/$_srcname/known_output_override.py" -t "$pkgdir/etc/pacroller"
    mkdir -p "$pkgdir/var/lib/pacroller"
    install -Dm644 "pacroller.service" "${pkgdir}/usr/lib/systemd/system/pacroller.service"
    install -Dm644 "pacroller.timer" "${pkgdir}/usr/lib/systemd/system/pacroller.timer"
}