PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45

pkgname=pacutils-git
pkgdesc='alpm front-end tools'
url='https://github.com/andrewgregory/pacutils'
pkgver=0.0.363
pkgrel=1
arch=('i686' 'x86_64')
depends=('pacman>=5.0')
makedepends=('git')
conflicts=('pacutils')
provides=("pacutils=$pkgver")
license=('MIT')
source=("$pkgname::git://github.com/andrewgregory/pacutils.git"
        "mini.c::git://github.com/andrewgregory/mINI.c.git"
        "tap.c::git://github.com/andrewgregory/tap.c.git")
sha1sums=('SKIP' 'SKIP' 'SKIP')

pkgver() {
    cd "$srcdir/$pkgname"
    echo "0.0.$(git rev-list --count HEAD)"
    #git describe --tags | sed 's/^v//; s/-/./g'
}

prepare() {
    cd "$srcdir/$pkgname"
    git submodule init
    git config submodule.ext/mini.c.url "$srcdir/mini.c"
    git config submodule.t/tap.c.url "$srcdir/tap.c"
    git submodule update
}

build() {
    cd "$srcdir/$pkgname"
    make SYSCONFDIR=/etc LOCALSTATEDIR=/var
}

check() {
    cd "$srcdir/$pkgname"
    make check
}

package() {
    cd "$srcdir/$pkgname"
    make DESTDIR="$pkgdir" PREFIX=/usr install
    install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}