blob: 6a0247d1ffe6a98944960003e729a94463187954 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
|
# Maintainer: WorMzy Tykashi <wormzy.tykashi@gmail.com>
# Contributor: artiom <a.mv at gmx dot fr>
# Contributor: ilikenwf
# Contributor: American_Jesus
pkgname=palemoon
_repo=Pale-Moon
pkgver=30.0.0
# Commit can be found at https://repo.palemoon.org/MoonchildProductions/Pale-Moon/releases
_commit=5a22267940
pkgrel=1
pkgdesc="Open source web browser based on Firefox focusing on efficiency."
arch=('i686' 'x86_64')
url="https://www.palemoon.org/"
license=('MPL' 'GPL' 'LGPL')
depends=('gtk2' 'dbus-glib' 'desktop-file-utils' 'libxt' 'mime-types' 'alsa-lib'
'startup-notification')
makedepends=('python2' 'autoconf2.13' 'unzip' 'zip' 'yasm' 'gcc10'
'libpulse' 'git')
optdepends=('libpulse: PulseAudio audio driver'
'ffmpeg: various video and audio support')
source=(git+"https://repo.palemoon.org/MoonchildProductions/${_repo}?signed#commit=${_commit}"
git+"https://repo.palemoon.org/MoonchildProductions/GRE"
mozconfig.in)
validpgpkeys=('3DAD8CD107197488D2A2A0BD40481E7B8FCF9CEC')
sha1sums=('SKIP'
'SKIP'
'49ded8cea5fffe4c8c8daec2335249988bc9c149')
sha256sums=('SKIP'
'SKIP'
'fe3c49964d7bbebc9fca844e5b4af12c52dac9187b87a98361788cfb6dd65fa7')
prepare() {
sed 's#%SRCDIR%#'"${srcdir}"'#g' mozconfig.in > mozconfig
cd ${_repo}
git submodule init
git config submodule.platform.url "${srcdir}/GRE"
git submodule update
}
build() {
cd ${_repo}
export MOZBUILD_STATE_PATH="${srcdir}/mozbuild"
export MOZCONFIG="${srcdir}/mozconfig"
export CPPFLAGS="${CPPFLAGS} -O2 -Wno-format-overflow"
./mach build
}
package() {
cd pmbuild
make package
cd dist
install -d "${pkgdir}"/usr/{bin,lib}
cp -r palemoon/ "${pkgdir}/usr/lib/${pkgname}"
ln -s "../lib/${pkgname}/palemoon" "${pkgdir}/usr/bin/palemoon"
# icons
install -Dm644 palemoon/chrome/icons/default/default16.png \
"${pkgdir}/usr/share/icons/hicolor/16x16/apps/${pkgname}.png"
install -Dm644 palemoon/chrome/icons/default/default32.png \
"${pkgdir}/usr/share/icons/hicolor/32x32/apps/${pkgname}.png"
install -Dm644 palemoon/chrome/icons/default/default48.png \
"${pkgdir}/usr/share/icons/hicolor/48x48/apps/${pkgname}.png"
install -Dm644 palemoon/icons/mozicon128.png \
"${pkgdir}/usr/share/icons/hicolor/128x128/apps/${pkgname}.png"
# install desktop file
install -Dm644 "${srcdir}/${_repo}/other-licenses/branding/palemoon/official/palemoon.desktop" "${pkgdir}/usr/share/applications/${pkgname}.desktop"
}
|