summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 71bbf89eea3293927a65c4d46ca14550af5a219f (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
# Maintainer: pancho horrillo <pancho at pancho dot name>
# Contributor: bender02 at archlinux dot us
# Contributor: Troels Kofoed Jacobsen <tkjacobsen at gmail dot com>

pkgname=pam_ssh
pkgver=2.1
pkgrel=5
pkgdesc='PAM module providing single sign-on behavior for SSH.'
arch=('i686' 'x86_64')
url='http://pam-ssh.sourceforge.net/'
license=('custom')
depends=('pam' 'openssl-1.0' 'openssh')
options=('!libtool')
install="$pkgname.install"
source=(
	"https://sourceforge.net/projects/pam-ssh/files/pam_ssh/2.1/pam_ssh-2.1.tar.xz"{,.asc}
)
sha512sums=(
	'8252b15efffa5687f740963f7a3c3479b73f99eca26a17155f915a10b9a71362a2778449adf10f01c174cc8545961ce3ea64459338a7c995c242b209529fd640'
	'SKIP'
)
validpgpkeys=(
	'501B088D8485568B87BB62BE180F6A5B3EDE742E'	# Wolfgang Rosenauer
)

build () {
	cd "$srcdir/$pkgname-$pkgver"
	CPPFLAGS+=' -I /usr/include/openssl-1.0' ./configure --prefix=/usr --with-pam-dir=/usr/lib/security --with-ssl-dir=/usr/lib/openssl-1.0
	make
}

package () {
	cd "$srcdir/$pkgname-$pkgver"
	CPPFLAGS+=' -I /usr/include/openssl-1.0' make DESTDIR="$pkgdir" install
	install -m 644 -D COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}