blob: 08f74c201fca5915cfceee2c0d63906a810f83ec (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer: David Manouchehri <manouchehri@riseup.net>
# Contributor: Maxime de Roucy <maxime.deroucy@gmail.com>
# Contributor: Niccolò Maggioni <nicco.maggioni@gmail.com>
pkgname="pam_u2f-git"
_gitname='pam-u2f'
_gitbranch='master'
_gitauthor='Yubico'
pkgver=1.0.2.r2.gb5729e8
pkgrel=1
pkgdesc="Universal 2nd Factor (U2F) PAM authentication module from Yubico"
url='https://developers.yubico.com/pam-u2f/'
license=('BSD')
source=("git://github.com/${_gitauthor}/${_gitname}#branch=${_gitbranch}")
sha512sums=('SKIP')
arch=('armv6h' 'armv7h' 'i686' 'x86_64')
depends=('pam' 'libu2f-host' 'libu2f-server')
makedepends=('git' 'autoconf' 'automake' 'asciidoc' 'libxslt' 'libxml2' 'docbook-xml' 'docbook-xsl')
conflicts=('pam_u2f')
provides=('pam_u2f')
pkgver() {
cd "${srcdir}/${_gitname}"
(
set -o pipefail
git describe --long 2>/dev/null | sed 's/pam_u2f-//;s/\([^-]*-g\)/r\1/;s/-/./g' ||
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
)
}
build() {
cd "${srcdir}/${_gitname}"
autoreconf --install
./configure \
--prefix=/usr \
--with-pam-dir=/usr/lib/security
make
}
check() {
cd "${srcdir}/${_gitname}"
make check
}
package() {
cd "${srcdir}/${_gitname}"
make DESTDIR="${pkgdir}/" install
mkdir -p "${pkgdir}/usr/share/licenses/${pkgname}"
cp COPYING "${pkgdir}/usr/share/licenses/${pkgname}/"
}
# vim:set et sw=2 sts=2 tw=80:
|