blob: 52809e338f40ab2d6fff817032bf7cd0c6e73e6f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# Maintainer: TommyTran732
# https://gitlab.manjaro.org/packages/extra/pamac
pkgname=pamac-flatpak-gnome
pkgver=10.1.3
pkgrel=4
_pkgfixver=$pkgver
pkgdesc="A Gtk3 frontend for libalpm (with AUR, Flatpak, AppIndicator support, and GNOME integration)"
arch=('i686' 'x86_64' 'arm' 'armv6h' 'armv7h' 'aarch64')
url="https://gitlab.manjaro.org/applications/pamac"
license=('GPL3')
depends=('libnotify' 'libpamac-flatpak' 'libhandy' 'libappindicator-gtk3' 'git' 'fakeroot' 'pkgconf')
makedepends=('gettext' 'itstool' 'vala>=0.45' 'meson' 'ninja' 'gobject-introspection' 'xorgproto' 'asciidoc')
conflicts=('pamac' 'pamac-cli' 'pamac-gtk' 'pamac-qt' 'pamac-classic' 'pamac-aur' 'pamac-aur-git' 'pamac-all' 'pamac-all-git' 'pamac-flatpak' 'gnome-software' 'pamac-tray-appindicator')
provides=('pamac' 'gnome-software')
options=(!emptydirs)
install=pamac.install
source=("pamac-$pkgver.tar.gz::$url/-/archive/v$pkgver/pamac-v$pkgver.tar.gz")
sha256sums=('577c0dfca155af9f4a7537b6c09bd37958ea5b5724c187f03239b27bd3d5951a')
prepare() {
cd "$srcdir/pamac-v$pkgver"
# adjust version string
sed -i -e "s|\"$_pkgfixver\"|\"$pkgver-$pkgrel\"|g" src/version.vala
}
build() {
cd "$srcdir/pamac-v$pkgver"
mkdir -p builddir
cd builddir
meson --prefix=/usr --sysconfdir=/etc -Denable-flatpak=true -Denable-appindicator=true -Denable-fake-gnome-software=true --buildtype=release
ninja
}
package() {
cd "$srcdir/pamac-v$pkgver/builddir"
DESTDIR="$pkgdir" ninja install
}
|