PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51

# Maintainer: Paris Oplopoios <parisoplop@gmail.com>

_pkgname=Panda3DS
_latest_release=0.4
_executable_name=Alber

pkgname=panda3ds-git
pkgver=0.4.r1203.d220d18
pkgrel=1
pkgdesc="HLE 3DS emulator"
arch=('x86_64')
#  TODO: Update when there's an actual website
url="https://github.com/wheremyfoodat/Panda3DS"
license=('GPL3')
depends=(
	gcc-libs
	libxext
)
makedepends=(
	cmake
	ninja
	git
	clang
)
provides=(panda3ds)
conflicts=(panda3ds)
source=("git+https://github.com/wheremyfoodat/Panda3DS")
sha256sums=('SKIP')

pkgver() {
	cd $_pkgname
	printf "%s.r%s.%s" \
	"$_latest_release" \
	"$(git rev-list --count HEAD)" \
	"$(git rev-parse --short HEAD)"
}


build() {
	export CXX=clang++
	export CC=clang
	cd $_pkgname
	git submodule update --init --recursive
	cmake -S . -B build -Wno-dev -DCMAKE_INSTALL_PREFIX=/usr -DCMAKE_BUILD_TYPE=Release -DENABLE_USER_BUILD=ON -DENABLE_VULKAN=OFF -GNinja
	cmake --build build -j$(nproc)
}

package() {
	cd $_pkgname
	install -vDm 755 "build/$_executable_name" "$pkgdir/usr/bin/$_pkgname"
}