blob: cb8374b22cabc7f1ddb5ca5cfb2675637a8f9c54 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
pkgname=pango-ubuntu
_pkgbase=pango
pkgver=1.40.3
pkgrel=1
pkgdesc="A library for layout and rendering of text (for compat with cairo-ubuntu, fontconfig-ubuntu)"
arch=('i686' 'x86_64')
license=('LGPL')
depends=('libthai' 'cairo-ubuntu' 'libxft' 'harfbuzz')
provides=("pango=$pkgver")
replaces=('pango')
conflicts=('pango')
makedepends=('harfbuzz' 'fontconfig-ubuntu' 'cairo-ubuntu' 'libxft' 'libthai' 'gobject-introspection' 'help2man')
checkdepends=('ttf-dejavu')
install=pango.install
source=(http://ftp.gnome.org/pub/GNOME/sources//${_pkgbase}/${pkgver:0:4}/${_pkgbase}-${pkgver}.tar.xz)
url="http://www.pango.org/"
md5sums=('17c26720f5a862a12f7e1745e2f1d966')
build() {
cd ${_pkgbase}-${pkgver}
rm -f pango-view/pango-view.1.in
./configure --prefix=/usr --sysconfdir=/etc \
--localstatedir=/var --with-included-modules=basic-fc
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
}
check() {
cd ${_pkgbase}-${pkgver}
make -k check || :
}
package() {
cd ${_pkgbase}-${pkgver}
make -j1 DESTDIR="${pkgdir}" install
}
|