blob: cce2e1b5d08613f126a51823f55123d975928f63 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer: Maxime Gauduin <alucryd@archlinux.org>
pkgname=pantheon-calendar-git
pkgver=r1398.528cd23
pkgrel=1
pkgdesc='The Pantheon Calendar'
arch=('i686' 'x86_64')
url='https://github.com/elementary/calendar'
license=('GPL3')
groups=('pantheon-unstable')
depends=('cairo' 'clutter' 'clutter-gtk' 'evolution-data-server' 'folks'
'gdk-pixbuf2' 'geocode-glib' 'glib2' 'glibc' 'gtk3' 'libchamplain'
'libgee' 'libical' 'libnotify' 'libsoup'
'libgranite.so')
makedepends=('cmake' 'git' 'granite-git' 'intltool' 'vala')
provides=('pantheon-calendar')
conflicts=('maya-calendar' 'pantheon-calendar')
replaces=('maya-calendar-bzr')
source=('pantheon-calendar::git+https://github.com/elementary/calendar.git')
sha256sums=('SKIP')
pkgver() {
cd pantheon-calendar
echo "r$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
}
prepare() {
cd pantheon-calendar
sed 's|${CMAKE_INSTALL_FULL_LIBDIR}|${CMAKE_INSTALL_PREFIX}/lib|g' -i $(grep -rl CMAKE_INSTALL_FULL_LIBDIR)
if [[ -d build ]]; then
rm -rf build
fi
mkdir build
}
build() {
cd pantheon-calendar/build
cmake .. \
-DCMAKE_BUILD_TYPE='Release' \
-DCMAKE_INSTALL_PREFIX='/usr' \
-DGSETTINGS_COMPILE='FALSE'
make
}
package() {
cd pantheon-calendar/build
make DESTDIR="${pkgdir}" install
}
# vim: ts=2 sw=2 et:
|