blob: 7acbdf1ef98d6ebcdb937c0bc59ac4ebf328f97f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Maintainer: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Riley Trautman <asonix@tamu.edu>
pkgname=pantheon-mail-git
pkgver=r2876.e1bb88dc
pkgrel=1
pkgdesc='The Pantheon Mail Client'
arch=('i686' 'x86_64')
url='https://github.com/elementary/mail'
license=('GPL3')
depends=('cairo' 'gcr' 'gdk-pixbuf2' 'glib2' 'glibc' 'gmime' 'gtk3'
'libaccounts-glib' 'libcanberra' 'libgee' 'libgsignon-glib'
'libsecret' 'libxml2' 'pango' 'sqlite' 'webkitgtk'
'libgranite.so')
makedepends=('cmake' 'git' 'gnome-doc-utils' 'gobject-introspection'
'granite-git' 'intltool' 'vala')
provides=('pantheon-mail')
conflicts=('pantheon-mail')
replaces=('pantheon-mail-bzr')
source=('pantheon-mail::git+https://github.com/elementary/mail.git')
sha256sums=('SKIP')
pkgver() {
cd pantheon-mail
echo "r$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
}
prepare() {
cd pantheon-mail
if [[ -d build ]]; then
rm -rf build
fi
mkdir build
}
build() {
cd pantheon-mail/build
cmake .. \
-DCMAKE_BUILD_TYPE='Release' \
-DCMAKE_INSTALL_PREFIX='/usr' \
-DDESKTOP_UPDATE='FALSE' \
-DGSETTINGS_COMPILE='FALSE' \
-DGSETTINGS_COMPILE_IN_PLACE='FALSE'
make
}
package() {
cd pantheon-mail/build
make DESTDIR="${pkgdir}" install
}
# vim: ts=2 sw=2 et:
|