blob: 59c6111305b907e1effd1b745f01b5eab98f1882 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: Maxime Gauduin <alucryd@archlinux.org>
pkgname=pantheon-polkit-agent-git
pkgver=0.1.4
pkgrel=1
pkgdesc='Pantheon Polkit Agent'
arch=('x86_64')
url='https://github.com/elementary/pantheon-agent-polkit'
license=('GPL3')
groups=('pantheon-unstable')
depends=('glib2' 'glibc' 'gtk3' 'polkit')
makedepends=('cmake' 'cmake-modules-elementary-git' 'git' 'intltool' 'vala')
provides=('pantheon-polkit-agent')
conflicts=('pantheon-polkit-agent')
source=('pantheon-polkit-agent::git+https://github.com/elementary/pantheon-agent-polkit.git')
sha256sums=('SKIP')
pkgver() {
cd pantheon-polkit-agent
git describe --tags | sed 's/-/.r/; s/-g/./'
}
prepare() {
cd pantheon-polkit-agent
if [[ -d build ]]; then
rm -rf build
fi
mkdir build
}
build() {
cd pantheon-polkit-agent/build
cmake .. \
-DCMAKE_BUILD_TYPE='Release' \
-DCMAKE_INSTALL_PREFIX='/usr'
make
}
package() {
cd pantheon-polkit-agent/build
make DESTDIR="${pkgdir}" install
}
# vim: ts=2 sw=2 et:
|