blob: aae84bf09ea71fd8a45cd3a14ff70bc80e215cc5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# Maintainer: Gordian Edenhofer <gordian.edenhofer@gmail.com>
pkgname=papermc
# curl -X GET "https://papermc.io/api/v2/projects/paper" -H "accept: application/json"
_pkgver=1.17.1
# curl -X GET "https://papermc.io/api/v2/projects/paper/versions/${_pkgver}" -H "accept: application/json"
_build=341
_license_commit=f25facb
pkgver="${_pkgver}+b${_build}"
pkgrel=1
pkgdesc="Next generation of Minecraft server, compatible with Spigot plugins and offering uncompromising performance"
arch=('any')
url="https://papermc.io/"
license=('custom')
depends=('java-runtime-headless>=16' 'tmux' 'sudo' 'bash' 'awk' 'sed')
optdepends=("tar: needed in order to create world backups"
"netcat: required in order to suspend an idle server")
conflicts=('papermc-git')
backup=('etc/conf.d/papermc')
install="${pkgname}.install"
source=("papermc.${pkgver}.jar"::"https://papermc.io/api/v2/projects/paper/versions/${_pkgver}/builds/${_build}/downloads/paper-${_pkgver}-${_build}.jar"
"papermc-backup.service"
"papermc-backup.timer"
"papermc.service"
"papermc.conf"
"papermc.sh"
"papermc.tmpfiles"
"papermc.sysusers"
"LICENSE_${pkgver}.md"::"https://raw.githubusercontent.com/PaperMC/Paper/${_license_commit}/LICENSE.md")
noextract=("papermc.${pkgver}.jar")
sha512sums=('f40e1448c96e786317df5db374832ce716245cf30235012f45faf1f074132445beb4f6a69d8cc5aa87ba17c340b9848aba4fa13bbf553bd6cdfec12aa6d3d4de'
'a4fcc9f28436c0163e9414f2793fcbd4f6ea74772230cdff4a628246eae2a8008688b3dfb94d433f8f0887cd7eea3fe43ce25f9d5812d46e62179ff315b62895'
'51c5345155e8640d4f1eaef0c8cfb890ae46063f2d4e7a0fe181ad4c8ff7b96fea88b0f9fc74031d589dfd61602f37b440f183ca1859835930fe69d37508cd42'
'f29c4044d9e3cc5ab137c21f7e62399b36d7e1f777d5558a39f7b4a01de75bdf2de0b8678e424accc03934ca7db9ebb6a22c78c8c4497759287dd55e1c3eb456'
'fe268d7380f881229100700b1d4f4897904a630aa65b0b06bba08be5d5918f208d497e01fc5306deecd5d93a78cfdb7e9c7f1c3b910b3a414ce9af186a05224d'
'4166db2684f41594128e25f036337f550f87697c7573d5c46e504c1deb994ef88a0f1b47527aa7e7e44d7cf03a1fcaa431d36293a29e9714bca60d5850be4f2d'
'c40cba5dfbf5af5d206cd42fa2b43f2321b481f83ab79c9ce4eaa76f204abab48ff2d8b8526a1a3d82636be97f18596d4343b0efc72a7082642e4af8d1b561c5'
'115fe7213d7edd0e3159607a31b28edb6e6b3bd1d454d516973e38c8cf0b803275c2c4e59b29e2260561270d931c71bad134046535e5add309e0a8d055cde0ff'
'3caa140e6545b7d61a182874cf5578050ad3f74c7e95fc5643b8c7594672bbbd9161381aa9c93b51248e12e60c6411d47fbb426ce3c22389bc8161c17278382e')
_game="papermc"
_server_root="/srv/papermc"
package() {
install -Dm644 ${_game}.conf "${pkgdir}/etc/conf.d/${_game}"
install -Dm755 ${_game}.sh "${pkgdir}/usr/bin/${_game}"
install -Dm644 ${_game}.service "${pkgdir}/usr/lib/systemd/system/${_game}.service"
install -Dm644 ${_game}-backup.service "${pkgdir}/usr/lib/systemd/system/${_game}-backup.service"
install -Dm644 ${_game}-backup.timer "${pkgdir}/usr/lib/systemd/system/${_game}-backup.timer"
install -Dm644 ${_game}.sysusers "${pkgdir}/usr/lib/sysusers.d/${_game}.conf"
install -Dm644 ${_game}.tmpfiles "${pkgdir}/usr/lib/tmpfiles.d/${_game}.conf"
install -Dm644 ${_game}.${pkgver}.jar "${pkgdir}/${_server_root}/${_game}.${pkgver}.jar"
ln -s "${_game}.${pkgver}.jar" "${pkgdir}${_server_root}/${_game}_server.jar"
# Link the log files
mkdir -p "${pkgdir}/var/log/"
install -dm2755 "${pkgdir}/${_server_root}/logs"
ln -s "${_server_root}/logs" "${pkgdir}/var/log/${_game}"
# Give the group write permissions and set user or group ID on execution
chmod g+ws "${pkgdir}${_server_root}"
install -D ./LICENSE_${pkgver}.md "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|