blob: 44684722d60c89579216d479a46142eba2712061 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
|
# Contributor: Gesh <gesh@gesh.uni.cx>
# Maintainer: Julian Hauser <julian at julianhauser.com>
# PKGBUILD adapted from papis, maintained by JP-Ellis <josh@jpellis.me>
pkgname=papis-git
_pkgname=papis
pkgver=0.13.r363.gd24ab05e
pkgrel=1
pkgdesc="Command-line document and bibliography manager"
arch=('any')
url="https://github.com/papis/papis"
license=('GPL-3.0-or-later')
makedepends=('git'
'python-build'
'python-installer'
'python-wheel'
'python-sphinx-click'
)
depends=('python'
'python-arxiv'
'python-beautifulsoup4'
'python-bibtexparser'
'python-chardet'
'python-click'
'python-colorama'
'python-doi'
'python-dominate'
'python-filetype'
'python-habanero'
'python-isbnlib'
'python-lxml'
'python-prompt_toolkit'
'python-pyaml'
'python-pygments'
'python-pyparsing'
'python-requests'
'python-slugify'
'python-stevedore'
'python-tqdm'
'python-typing_extensions'
)
optdepends=(
'fzf: fzf picker'
'papis-rofi: integration with rofi'
'papis-zotero: imports from zotero'
'pdfjs: pdf reader in the web app'
'python-jinja: jinja formatting'
'python-papis-scihub: imports from scihub'
'python-markdownify: convert zenodo imports to markdown'
'python-whoosh: whoosh database backend'
)
checkdepends=(
# For pytest
python-pytest
python-pytest-cov
# These are optional -- if they're not installed, papis will automatically
# skip these tests -- and are only necessary if you intend to use the
# optdeps as well
python-jinja
python-markdownify
python-whoosh
# For flake8
flake8
python-flake8-bugbear
python-flake8-polyfill
python-flake8-quotes
python-pep8-naming
python-pylint
# For mypy
mypy
python-pytest-mypy
python-types-beautifulsoup4
python-types-pyaml
python-types-pygments
python-types-requests
python-types-setuptools
python-types-tqdm
)
provides=("papis")
conflicts=("papis")
source=("git+https://github.com/papis/papis.git")
sha256sums=('SKIP')
pkgver() {
cd "${_pkgname}"
git describe --long --tags | sed 's/v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
check() {
cd "${_pkgname}"
python -m pytest papis tests
python -m flake8 papis tests examples
python -m mypy papis
}
build() {
cd "${_pkgname}"
python -m build --wheel --no-isolation
}
package() {
cd "${_pkgname}"
python -m installer --destdir="$pkgdir" dist/*.whl
}
|