PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

# vim:set ft=sh:
# Maintainer: BlackEagle < ike DOT devolder AT gmail DOT com >
pkgname=par2cmdline-git
_gitname='par2cmdline'
pkgver=20261015.87f62a2
pkgrel=1
pkgdesc="A file verification and repair tool"
url="https://github.com/BlackIkeEagle/par2cmdline"
license=("GPL")
makedepends=('git' 'tar' 'cmake' 'ninja')
depends=('gcc-libs')
arch=('x86_64')
provides=('par2cmdline')
conflicts=('par2cmdline')
source=("$_gitname::git+https://github.com/BlackIkeEagle/par2cmdline.git")
sha256sums=('SKIP')

pkgver() {
    cd "$srcdir/$_gitname"
    git log -1 --date=short --format="%cd.%h" | tr -d '-'
}

build() {
    cmake \
        -S ${_gitname} \
        -B build \
        -G Ninja \
        -DCMAKE_BUILD_TYPE=Release \
        -DPAR2_KEEP_ASSERTS=ON
    cmake --build build
}

check() {
    ctest --test-dir build
}

package() {
    DESTDIR=$pkgdir cmake \
        --install build \
        --prefix /usr
}