blob: ca03c769cb502c936cc0f71d1b2a535d102c4c70 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Maintainer: a821
# Contributor: Angel de Vicente <angel.vicente.garrido at gmail dot com>
pkgname="parallel-git"
pkgver=20250522.r0.g4298ce8b
pkgrel=1
pkgdesc="A shell tool for executing jobs in parallel"
arch=('any')
url="https://www.gnu.org/software/parallel/"
license=('GPL-3.0-or-later')
depends=('perl' 'texinfo')
makedepends=('git')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=("${pkgname%-git}::git+https://git.savannah.gnu.org/git/parallel.git"
'0001-Remove-citation-things.patch'
'0002-skip-rst-pdf-generation.patch')
sha256sums=('SKIP'
'bd7f1446529f5a196a0190c5db84ee69b7646a7464531a5ae291c38f52f5a0e1'
'85eae9f01bdb8d7ab14b0a3e266ae7e9d5582b77b2a81493225daddedab87e7e')
pkgver() {
cd "${pkgname%-git}"
git describe --long --tags | sed 's/\([^-]*-\)g/r\1g/;s/-/./g'
}
prepare() {
cd "${pkgname%-git}"
cat ../*.patch | patch -p1
autoreconf -fvi
}
build() {
cd "${pkgname%-git}"
./configure --prefix=/usr
make
}
package() {
cd "${pkgname%-git}"
make DESTDIR="$pkgdir/" install
}
|