blob: bbb90a9e0bdc8a777b51e68eeaa5ade7907a6424 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: Gustavo Alvarez <sl1pkn07@gmail.com>
# Contributor: A Rojas < nqn1976 @ gmail.com >
pkgname=partitionmanager-git
pkgver=1.9.50.r944.de9f34a
pkgrel=1
pkgdesc="A KDE utility that allows you to manage disks, partitions, and file systems. (GIT version)"
arch=('i686' 'x86_64')
url='http://kde.org/applications/system/kdepartitionmanager'
license=('GPL2')
depends=('kpmcore-git' 'hicolor-icon-theme')
conflicts=('partitionmanager')
provides=('partitionmanager')
makedepends=('extra-cmake-modules' 'kdoctools' 'git' 'python')
optdepends=('e2fsprogs: ext2/3/4 support'
'xfsprogs: XFS support'
'jfsutils: JFS support'
'reiserfsprogs: Reiser support'
'ntfsprogs: NTFS support'
'dosfstools: FAT32 support')
source=('git://anongit.kde.org/partitionmanager')
sha1sums=('SKIP')
install=partitionmanager-git.install
pkgver() {
cd partitionmanager
_ver="$(cat CMakeLists.txt | grep -m3 -e VERSION_MAJOR -e VERSION_MINOR -e VERSION_RELEASE | cut -d '"' -f2 | paste -sd'.')"
echo "${_ver}.r$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
}
prepare() {
mkdir -p build
}
build() {
cd build
cmake ../partitionmanager \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr \
-DLIB_INSTALL_DIR=lib \
-DKDE_INSTALL_USE_QT_SYS_PATHS=ON \
-DBUILD_TESTING=OFF
make
}
package() {
make -C build DESTDIR="${pkgdir}" install
}
|