blob: 3dcf9cbd77db99b627f9f233a90d6f803aa7e929 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Maintainer: Morgan <morganamilo@archlinux.org>
pkgname=paru
pkgver=0.99.0
pkgrel=2
pkgdesc='AUR helper based on yay'
url='https://github.com/morganamilo/paru'
source=("$pkgname-$pkgver::https://github.com/Morganamilo/paru/archive/v$pkgver.tar.gz")
backup=("etc/paru.conf")
arch=('x86_64' 'i686')
license=('GPL3')
makedepends=('cargo')
depends=('git' 'pacman')
optdepends=('asp: downloading repo pkgbuilds')
sha256sums=('9956082d2af9475d310e5f064780392697f675f2b3d1dd445e128f81523a7809')
build () {
cd "$srcdir/$pkgname-$pkgver"
if pacman -T pacman-git > /dev/null; then
_features+="git,generate,"
fi
if [[ $(rustc -V) == *"nightly"* ]]; then
_features+="backtrace,"
fi
cargo build --features "${_features:-}" --release
}
package() {
cd "$srcdir/$pkgname-$pkgver"
install -Dm755 target/release/paru "${pkgdir}/usr/bin/paru"
install -Dm644 paru.conf "${pkgdir}/etc/paru.conf"
install -Dm644 man/paru.8 "$pkgdir/usr/share/man/man8/paru.8"
install -Dm644 man/paru.conf.5 "$pkgdir/usr/share/man/man5/paru.conf.5"
install -Dm644 completions/bash "${pkgdir}/usr/share/bash-completion/completions/paru.bash"
install -Dm644 completions/fish "${pkgdir}/usr/share/fish/completions/paru.fish"
install -Dm644 completions/zsh "${pkgdir}/usr/share/zsh/functions/Completion/Linux/_paru"
}
|