blob: 77bc593b5d9e4a5ecd1567067024f0008ea632a7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
pkgname=patchelf-git
pkgver=0.18.0.r12.g917ea45
pkgrel=2
pkgdesc="A small utility to modify the dynamic linker and RPATH of ELF executables"
arch=('i686' 'x86_64')
url="https://github.com/NixOS/patchelf"
license=('GPL3')
depends=('gcc-libs')
makedepends=('git')
provides=("patchelf=$pkgver")
conflicts=('patchelf')
source=("git+https://github.com/NixOS/patchelf.git")
sha256sums=('SKIP')
pkgver() {
cd "patchelf"
_tag=$(git tag -l --sort -v:refname | grep -E '^v?[0-9\.]+$' | head -n1)
_rev=$(git rev-list --count $_tag..HEAD)
_hash=$(git rev-parse --short HEAD)
printf "%s.r%s.g%s" "$_tag" "$_rev" "$_hash" | sed 's/^v//'
}
build() {
cd "patchelf"
./bootstrap.sh
./configure \
--prefix="/usr"
make
}
check() {
cd "patchelf"
make check
}
package() {
cd "patchelf"
make DESTDIR="$pkgdir" install
}
|