PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71

# Maintainer: Sam L. Yes <samlukeyes123 at gmail dot com>

pkgname=pbuilder-git
pkgver=0.231.r20.ga7a3f03e
pkgrel=1
pkgdesc="Personal package builder for Debian packages"
arch=('any')
license=('GPL')
url='https://pbuilder-team.pages.debian.net/pbuilder'
depends=('debootstrap' 'dpkg' 'inetutils')
optdepends=('ubuntu-keyring: checking release signatures of ubuntu distributions'
            'debian-archive-keyring: checking release signatures of debian distributions'
            'debian-keyring: checking release signatures of debian distributions (alternative package)')
makedepends=('git')
checkdepends=('man-db')
provides=('pbuilder')
conflicts=('pbuilder')
backup=('etc/pbuilderrc')
options=('emptydirs')
source=("git+https://salsa.debian.org/pbuilder-team/pbuilder.git")
sha512sums=('SKIP')

prepare() {
    cd ${srcdir}/pbuilder

    # Not building documents
    sed -i 's/$(MAKE) -C Documentation/#$(MAKE) -C Documentation/' Makefile
}

pkgver() {
    cd pbuilder

    # Reference: https://wiki.archlinux.org/title/VCS_package_guidelines#Git
    git describe --long | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "${srcdir}/pbuilder"

  make
}

check() {
  cd "${srcdir}/pbuilder"

  make check
}

package() {
  cd "${srcdir}/pbuilder"

  make install DESTDIR="${pkgdir}" SBINDIR="${pkgdir}/usr/bin"
  install -Dm644 -t "${pkgdir}/usr/share/man/man1/" debuild-pbuilder.1 pdebuild.1
  install -Dm644 -t "${pkgdir}/usr/share/man/man5/" pbuilderrc.5
  install -Dm644 -t "${pkgdir}/usr/share/man/man8/" pbuilder.8

  for i in 'aptcache' 'build' 'ccache' 'result'
  do
    install -d "${pkgdir}/var/cache/pbuilder/$i"
  done

  cat <<EOF > "${pkgdir}/etc/pbuilderrc"
# this is your configuration file for pbuilder.
# the file in /usr/share/pbuilder/pbuilderrc is the default template.
# /etc/pbuilderrc is the one meant for overwriting defaults in
# the default template
#
# read pbuilderrc.5 document for notes on specific options.
MIRRORSITE=http://please-choose-a-valid-mirror.example.com/
EOF
}