blob: df16ce24da8429db738e05515be755394876e901 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
|
# Maintainer: dreieck (https://aur.archlinux.org/account/dreieck)
_pkgname=pdfrip
pkgname="${_pkgname}-git"
pkgver=2.0.1+22.r80.20240618.461fe2f
pkgrel=1
arch=(
'i686'
'x86_64'
'armv7h'
'aarch64'
)
pkgdesc='A multi-threaded PDF password recovering/ cracking utility.'
url='https://github.com/mufeedvh/pdfrip'
license=('MIT')
depends=(
'gcc-libs'
'glibc'
)
makedepends=(
'base-devel'
'git'
'gifsicle'
'zopfli'
'rust'
)
optdepends=()
provides=(
"${_pkgname}=${pkgver}"
)
conflicts=(
"${_pkgname}"
)
source=(
"${_pkgname}::git+${url}.git"
)
sha256sums=(
'SKIP' # Main upstream source
)
# options+=('!lto')
prepare() {
cd "${srcdir}/${_pkgname}"
CARGO_HOME="${srcdir}/cargo"
export CARGO_HOME
cargo fetch
git log > "${srcdir}/git.log"
}
pkgver() {
cd "${srcdir}/${_pkgname}"
_ver="$(git describe --tags | sed -E -e 's|^[vV]||' -e 's|-g[0-9a-f]*$||' -e 's|-|+|g')"
_rev="$(git rev-list --count HEAD)"
_date="$(git log -1 --date=format:"%Y%m%d" --format="%ad")"
_hash="$(git rev-parse --short HEAD)"
if [ -z "${_ver}" ]; then
error "Version could not be determined."
return 1
else
printf '%s' "${_ver}.r${_rev}.${_date}.${_hash}"
fi
}
build() {
cd "${srcdir}/${_pkgname}"
# shrinking PNG and GIF files losslessy:
local _png _gif
for _png in screenshots/*.png; do
zopflipng -y -m "${_png}" "${_png}"
done
for _gif in screenshots/*.gif; do
gifsicle -O3 -V -o "${_gif}" "${_gif}"
done
CARGO_HOME="${srcdir}/cargo"
export CARGO_HOME
cargo build --offline --release
}
check() {
cd "${srcdir}/${_pkgname}"
CARGO_HOME="${srcdir}/cargo"
export CARGO_HOME
cargo test --offline
}
package() {
cd "${srcdir}/${_pkgname}"
CARGO_HOME="${srcdir}/cargo"
export CARGO_HOME
# Install manually:
install -Dvm755 -t "${pkgdir}/usr/bin" target/release/pdfrip
for _docfile in README.md screenshots/* examples/*; do
install -D -v -m644 "${_docfile}" "${pkgdir}/usr/share/doc/${_pkgname}/${_docfile}"
done
install -D -v -m644 "${srcdir}/git.log" "${pkgdir}/usr/share/doc/${_pkgname}/git.log"
install -D -v -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
cd "${pkgdir}/usr/share/doc/${_pkgname}"
ln -sv "/usr/share/licenses/${pkgname}/LICENSE" "LICENSE"
}
|