blob: bec79c9783d3e96de81eb391638501e4639b40f3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# Maintainer: Philipp Wolfer <ph.wolfer@gmail.com>
_pkgname=peek
pkgname=${_pkgname}-git
pkgver=1.3.0.r0.g17c2a61
pkgrel=1
pkgdesc="Simple screen recorder with an easy to use interface (latest development release)"
arch=('i686' 'x86_64')
url="https://github.com/phw/peek"
license=('GPL3')
provides=("${_pkgname}=${pkgver}")
conflicts=("${_pkgname}")
depends=(gtk3 libkeybinder3 ffmpeg)
makedepends=(git cmake vala gettext txt2man)
optdepends=(
'gst-plugins-good: Recording under Gnome Shell'
'gst-plugins-ugly: MP4 output under Gnome Shell'
'gifski: High quality GIF animations with thousands of colors'
)
source=(git+https://github.com/phw/${_pkgname}.git)
sha1sums=('SKIP')
prepare() {
mkdir -p build
}
build() {
cd "build"
cmake ${srcdir}/${_pkgname}\
-DCMAKE_INSTALL_PREFIX=/usr \
-DBUILD_TESTS=ON \
-DCMAKE_BUILD_TYPE=Release \
-DGSETTINGS_COMPILE=OFF \
-DENABLE_FILECHOOSERNATIVE=ON
make
}
check() {
cd "build"
make test
}
package() {
cd "build"
make DESTDIR=${pkgdir} install
}
pkgver() {
cd "${srcdir}/${_pkgname}"
git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
|