blob: c7588e84e39d3d77b55cab27ea907a3826a3f9ef (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
|
# Maintainer: Balló György <ballogyor+arch at gmail dot com>
# Contributor: Alex Wiggins <alex.d.wiggins at gmail . com>
pkgname=penguin-subtitle-player
pkgver=1.6.0
pkgrel=1
pkgdesc='Standalone subtitle player'
arch=('x86_64')
url='https://github.com/carsonip/Penguin-Subtitle-Player'
license=('GPL3')
depends=('hicolor-icon-theme' 'qt5-base' 'uchardet')
source=("https://github.com/carsonip/Penguin-Subtitle-Player/archive/v${pkgver}/$pkgname-$pkgver.tar.gz")
sha256sums=('fdc34d234c7f632ec2ebbf84af9aefac6ea504bb5de7323c63cfaa0acf095b06')
prepare() {
cd Penguin-Subtitle-Player-$pkgver
# Unbundle uchardet
sed -i '/src\/uchardet/d' PenguinSubtitlePlayer.pro
sed -i 's|uchardet/src/uchardet.h|uchardet/uchardet.h|' src/chardet.cpp
}
build() {
cd Penguin-Subtitle-Player-$pkgver
qmake-qt5 PREFIX=/usr PenguinSubtitlePlayer.pro LIBS+=" -luchardet"
make
}
package() {
cd Penguin-Subtitle-Player-$pkgver
make INSTALL_ROOT="$pkgdir" install
}
|