PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48

# Maintainer: xRemaLx <anton.komolov@gmail.com>
# Contributor: AUR Perl <aurperl@juster.info>

pkgname='perl-carp-assert'
pkgver='0.21'
pkgrel='2'
pkgdesc="executable comments"
_dist='Carp-Assert'
arch=('any')
url='http://search.cpan.org/dist/Carp-Assert'
license=('PerlArtistic' 'GPL')
depends=('perl')
options=('!emptydirs' purge)
makedepends=()
checkdepends=()
source=("http://search.cpan.org/CPAN/authors/id/N/NE/NEILB/${_dist}-${pkgver}.tar.gz")
sha512sums=('9fb96ebaf03a86edcd0262b5216b345839dc99e504738e52f883932e425cac33470fcb0e8e4653488c0d8e63e9904af311056213c63ae40bc3935eec4c0410a0')

sanitize() {
  unset PERL5LIB PERL_MM_OPT PERL_LOCAL_LIB_ROOT
  export PERL_MM_USE_DEFAULT=1 PERL_AUTOINSTALL=--skipdeps
}

build() {
  cd "${srcdir}/${_dist}-${pkgver}"
  sanitize
  /usr/bin/perl Makefile.PL
  make
}

check() {
  cd "${srcdir}/${_dist}-${pkgver}"
  sanitize
  make test
}

package() {
  cd "${srcdir}/${_dist}-${pkgver}"
  sanitize
  make install INSTALLDIRS=vendor DESTDIR="$pkgdir"
  find "$pkgdir" -name .packlist -o -name perllocal.pod -delete
}

# Local Variables:
# mode: shell-script
# sh-basic-offset: 2
# End:
# vim:set ts=2 sw=2 et: