blob: 8f3946f0321b5152708c32e43c6c7a0de25a3ffc (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Moritz Bunkus <moritz@bunkus.org>
pkgname='perl-net-sip'
pkgver='0.807'
pkgrel='1'
pkgdesc="SIP (Voice Over IP, RFC3261) packet handling"
arch=('any')
license=('PerlArtistic')
options=('!emptydirs')
depends=('perl-net-dns')
url='http://search.cpan.org/dist/Net-SIP'
source=("https://cpan.metacpan.org/authors/id/S/SU/SULLR/Net-SIP-${pkgver}.tar.gz")
sha512sums=('6bf14780b35567564861e16f42a6c80d2e40d7a6806a75a30dd551a21bbd38f4f46c40b8c46b6f5301acdd6a1d4733dbded516a0a398bf359f3d693b3b91cda8')
prepare_environment() {
export PERL_MM_USE_DEFAULT=1 PERL5LIB="" \
PERL_AUTOINSTALL=--skipdeps \
PERL_MM_OPT="INSTALLDIRS=vendor DESTDIR='$pkgdir'" \
PERL_MB_OPT="--installdirs vendor --destdir '$pkgdir'" \
MODULEBUILDRC=/dev/null
cd "${srcdir}/Net-SIP-${pkgver}"
}
build() {
prepare_environment
/usr/bin/perl Makefile.PL
make
}
check() {
prepare_environment
make test
}
package() {
prepare_environment
make install
find "$pkgdir" -name .packlist -o -name perllocal.pod -delete
}
# Local Variables:
# mode: shell-script
# sh-basic-offset: 2
# End:
# vim:set ts=2 sw=2 et:
|