blob: a1d831b1d9f5d827668a29590848c8722fbb0019 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
|
# Maintainer: Amish <contact at via dot aur>
# Contributor: John D Jones III AKA jnbek <jnbek1972 -_AT_- g m a i l -_Dot_- com>
pkgname=perl-text-csv-xs
pkgver=1.40
pkgrel=1
pkgdesc="Comma-separated values manipulation routines"
_dist=Text-CSV_XS
arch=('any')
url="https://metacpan.org/release/${_dist}"
license=('GPL' 'PerlArtistic')
depends=('perl')
options=('!emptydirs' purge)
source=("https://cpan.metacpan.org/authors/id/H/HM/HMBRAND/${_dist}-${pkgver}.tgz")
md5sums=('fcb9183f2716fe3c13d5e0e602285840')
sha512sums=('1570c6ff08487603e428d889e9f917766ff8d053727924db6b5f2ab28b0161faa9496d44eba2f466ea2447b1ec8491313857cb447a948a0b9194a6e1c56e961c')
build() {
cd "${srcdir}/${_dist}-${pkgver}"
unset PERL5LIB PERL_MM_OPT PERL_LOCAL_LIB_ROOT
export PERL_MM_USE_DEFAULT=1 PERL_AUTOINSTALL=--skipdeps
/usr/bin/perl Makefile.PL
make
}
check() {
cd "${srcdir}/${_dist}-${pkgver}"
unset PERL5LIB PERL_MM_OPT PERL_LOCAL_LIB_ROOT
export PERL_MM_USE_DEFAULT=1
make test
}
package() {
cd "${srcdir}/${_dist}-${pkgver}"
unset PERL5LIB PERL_MM_OPT PERL_LOCAL_LIB_ROOT
make install INSTALLDIRS=vendor DESTDIR="${pkgdir}"
}
|