PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42

# Maintainer: Andy Weidenbaum <archbaum@gmail.com>

pkgname=perl6-cro-http-session-redis
pkgver=0.7.3
pkgrel=1
pkgdesc="A role to help with persisting Cro HTTP sessions using Redis"
arch=('any')
depends=('perl6'
         'perl6-cro-http'
         'perl6-redis-async')
checkdepends=('perl' 'perl6-test-meta')
makedepends=('git')
groups=('croservices' 'perl6')
url="https://github.com/croservices/cro-http-session-redis"
license=('PerlArtistic')
source=($pkgname-$pkgver::git+https://github.com/croservices/cro-http-session-redis)
sha256sums=('SKIP')

check() {
  cd "$srcdir/$pkgname-$pkgver"

  msg2 'Running tests...'
  PERL6LIB=lib prove -r -e perl6 t/
}

package() {
  cd "$srcdir/$pkgname-$pkgver"

  msg2 'Installing license...'
  install -Dm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"

  msg2 'Installing documentation...'
  install -Dm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname"

  msg2 'Installing...'
  export RAKUDO_LOG_PRECOMP=1
  export RAKUDO_RERESOLVE_DEPENDENCIES=0
  perl6-install-dist \
    --to="$pkgdir/usr/share/perl6/vendor" \
    --for=vendor \
    --from=.
}