blob: e017fe92d5546f2e2c01a6539f8ea6a019578cd4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
|
# Maintainer: Brian Bidulock <bidulock@openss7.org>
pkgname=perlpanel-git
pkgver=0.9.1.37
pkgrel=1
pkgdesc="The ideal accompaniment to a light-weight Window Manager such as OpenBox, or a desktop-drawing program like iDesk."
arch=('any')
#url="http://savannah.nongnu.org/projects/perlpanel"
url="https://github.com/bbidulock/perlpanel"
license=('GPL')
provides=('perlpanel')
conflicts=('perlpanel' 'perlpanel-light')
options=('!emptydirs')
install=perlpanel.install
depends=('glade-perl' 'gnome-vfs-perl' 'perl-timedate' 'perl-gnome2-wnck'
'perl-locale-gettext' 'perl-xml-parser' 'perl-xml-simple')
optdepends=('perl-xmms: XMMS applet'
'xdg-traymenu: XDGMenu applet'
'perl-hardware-sensorparser: Sensors applet')
source=("$pkgname::git+https://github.com/bbidulock/perlpanel.git")
md5sums=('SKIP')
pkgver() {
cd $pkgname
git describe --tags | sed 's,release-,,;s,-g.*$,,;s,[-_],.,g'
}
build() {
cd $pkgname
make PREFIX="/usr" VERSION="$pkgver"
}
package() {
cd $pkgname
make PREFIX="/usr" VERSION="$pkgver" DESTDIR="$pkgdir" install
find $pkgdir -name '.packlist' -exec rm '{}' \;
find $pkgdir -name 'perllocal.pod' -exec rm '{}' \;
}
|