blob: 53df85fc9bdf6aec1838ac74217e9a703c77f5cb (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# Maintainer: bko <aur at bil dot co dot ua>
pkgname=pgadmin4-server
pkgver=9.12
pkgrel=1
pkgdesc='The core server package for pgAdmin. pgAdmin is the most popular and feature rich Open Source administration and development platform for PostgreSQL, the most advanced Open Source database in the world.'
arch=('x86_64')
license=('PostgreSQL')
url='https://www.pgadmin.org/'
depends=('postgresql-libs' 'krb5' 'python-dbus')
makedepends=("python" "python-pip" "postgresql-libs" "gcc" "nodejs" "corepack" "pkgconf" "cmake" "dbus" "npm" "wget" "unzip" "syft" "patch")
provides=('pgadmin4-server')
source=("pgadmin4-${pkgver}.tar.gz::https://ftp.postgresql.org/pub/pgadmin/pgadmin4/v${pkgver}/source/pgadmin4-${pkgver}.tar.gz" "server.patch")
sha256sums=('f72f5d688eed9f65d523046492ce868bcb4251c04f763cb6b834b13be0ad6744' 'd276423ab3eaa7abaf14e720c51f49cc18a528d2e1b6324d4d05257d5d58f556')
prepare() {
cd "$srcdir/pgadmin4-${pkgver}"
patch -p1 <"../server.patch"
}
build() {
cd "$srcdir/pgadmin4-${pkgver}"
export COREPACK_HOME="$srcdir/corepack_home"
mkdir -p "$COREPACK_HOME/bin"
corepack enable --install-directory "$COREPACK_HOME/bin"
export PATH="$COREPACK_HOME/bin:$PATH"
export COREPACK_ENABLE_DOWNLOAD_PROMPT=0
corepack prepare yarn@stable --activate
pushd . && cd web
yarn install && yarn run bundle
popd
python -m venv venv
venv/bin/python3 -m pip install --no-cache-dir -r requirements.txt
venv/bin/python3 -m pip install --no-cache-dir sphinx sphinxcontrib-youtube
source venv/bin/activate
export PYTHONDONTWRITEBYTECODE=1
source pkg/linux/build-functions.sh
_setup_env "${PWD}/pkg/linux/DUMMY" "arch"
_cleanup "pkg.tar.zst"
_setup_dirs
_create_python_virtualenv "arch"
_build_docs "arch"
_copy_code "arch"
_generate_sbom
}
package() {
cp -r "${srcdir}/pgadmin4-${pkgver}/arch-build/server/usr" "${pkgdir}/"
# Install license
install -Dm644 "$srcdir/pgadmin4-${pkgver}/LICENSE" \
"${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|