PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

# Maintainer: Baudouin Feildel <baudouin_aur@feildel.fr>
pkgname=pgpointcloud
pkgver=1.2.0
pkgrel=3
pkgdesc="A PostgreSQL extension for storing point cloud (LIDAR) data"
arch=('i686' 'x86_64')
url="https://github.com/pgpointcloud/pointcloud"
license=('BSD')
depends=('libxml2')
optdepends=('laz-perf: LAZ compression support')
makedepends=('cunit' 'laz-perf')
provides=("pgpointcloud=$pkgver")
conflicts=('pgpointcloud-git')
changelog="$pkgname.changelog"
source=(
	"https://github.com/pgpointcloud/pointcloud/archive/v$pkgver.tar.gz"
	"${pkgname#pg}-$pkgver-fix-compilation-against-pg11.patch")
sha256sums=(
	'8542a4c714b4d0c67f10d092291a43b5650871b4ec8caf831e492810f25bb93c'
	'aa6b1c74aa88e7ec70b78bcb1125a6458ab99261f0debc385ddf6616fe8f628e')

prepare() {
	cd "${pkgname#pg}-$pkgver"
	patch -p1 -i "$srcdir/${pkgname#pg}-$pkgver-fix-compilation-against-pg11.patch"
}

build() {
	cd "${pkgname#pg}-$pkgver"

	./autogen.sh
	./configure --prefix=/usr
	make
}

check() {
	cd "${pkgname#pg}-$pkgver"

	make check
}

package() {
	cd "${pkgname#pg}-$pkgver"

	install -Dm644 COPYRIGHT "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
	install -Dm644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
	make DESTDIR="$pkgdir/" install
}