PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49

# Maintainer: Philip Goto <philip.goto@gmail.com>

pkgname=phoc-embedded-wlroots
pkgver=0.20.0
pkgrel=1
pkgdesc='Wlroots based Phone compositor (matching wlroots embedded)'
arch=(x86_64 aarch64)
url='https://gitlab.gnome.org/World/Phosh/phoc'
license=(GPL3)
depends=(
	mutter
	seatd
	xcb-util-errors
	xcb-util-renderutil
	xcb-util-wm
)
makedepends=(
	ctags
	git
	libhandy
	meson
	vala
	vulkan-headers
	wayland-protocols
)
provides=(phoc)
conflicts=(phoc wlroots)
source=(
	"git+${url}.git#tag=v${pkgver}"
	"git+https://source.puri.sm/Librem5/wlroots.git"
)
b2sums=('SKIP' 'SKIP')

prepare() {
	cd phoc

	git submodule init
	git submodule set-url subprojects/wlroots "${srcdir}/wlroots"
	git submodule update
}

build() {
	arch-meson phoc build -Dembed-wlroots=enabled
	meson compile -C build
}

package() {
	DESTDIR="${pkgdir}" meson install -C build
}