PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54

# Maintainer: Thomas Booker <tw.booker@outlook.com>
# Contributor: Philip Goto <philip.goto@gmail.com>

pkgname=phoc-embedded-wlroots
pkgver=0.21.0
pkgrel=1
pkgdesc='A pure Wayland shell prototype for GNOME on mobile devices (wlroots embedded)'
arch=(x86_64 aarch64 armv7h)
url='https://gitlab.gnome.org/World/Phosh/phoc'
license=(GPL3)
depends=(
	gobject-introspection
	gnome-desktop
	libinput
	mutter
	libseat.so
	xcb-util-errors
	xcb-util-wm
	xcb-util-renderutil
	glslang
)
makedepends=(
	meson
	git
	vulkan-headers
	wayland-protocols
	xorg-xwayland
)
provides=(phoc wlroots)
conflicts=(phoc wlroots)
_tag=1a58a2363b686241647138a8822beac4f761f3fb
source=("git+${url}.git#tag=${_tag}")
sha256sums=('SKIP')

pkgver() {
	cd phoc
	git describe --tags | sed 's/^v//'
}

prepare() {
	cd phoc

	git submodule init
	git submodule update
}

build() {
	arch-meson phoc _build -Dembed-wlroots=enabled -Dtests=false
	meson compile -C _build
}

package() {
	DESTDIR="${pkgdir}" meson install -C _build
}