blob: 808765aad4a494b120e3db1353d6aaff3deee771 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# Maintainer: Philip Goto <philip.goto@gmail.com>
pkgname=phosh-git
pkgver=0.14.0.r31.g46b4f0f
pkgrel=1
pkgdesc='A pure Wayland shell prototype for GNOME on mobile devices'
url='https://gitlab.gnome.org/World/Phosh/phosh'
license=('GPL3')
arch=(x86_64 aarch64 armv7h)
depends=(
callaudiod
feedbackd
libhandy
phoc
)
makedepends=(
ctags
git
meson
vala
wayland-protocols
)
provides=(phosh)
conflicts=(phosh)
# checkdepends=(xorg-server-xvfb)
source=(
"git+${url}.git"
"git+https://gitlab.gnome.org/GNOME/libgnome-volume-control.git"
)
sha256sums=('SKIP' 'SKIP')
pkgver() {
cd phosh
git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd phosh
git submodule init
git config --local submodule.subprojects/gvc.url "$srcdir/libgnome-volume-control"
git submodule update
}
build() {
arch-meson phosh build # -D gtk_doc=true
meson compile -C build
}
# check() {
# dbus-run-session xvfb-run \
# -s '-screen 0 1920x1080x24 -nolisten local' \
# meson test -C build --print-errorlogs
# }
package() {
DESTDIR="${pkgdir}" meson install -C build
}
|