blob: 6ed4a8ff5b5ddcf3083700818ef367eb3a449529 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# Maintainer: Thomas Booker <tw.booker@outlook.com>
# Contributor: Philip Goto <philip.goto@gmail.com>
pkgname=phosh-git
pkgver=0.20.0.r22.g1c471472
pkgrel=1
pkgdesc='A pure Wayland shell prototype for GNOME on mobile devices'
arch=(x86_64 aarch64 armv7h)
url='https://gitlab.gnome.org/World/Phosh/phosh'
license=(GPL3)
depends=(
callaudiod
feedbackd
libhandy
phoc
polkit
)
makedepends=(
ctags
git
meson
vala
wayland-protocols
)
provides=(phosh)
conflicts=(phosh)
source=("git+${url}.git")
sha256sums=('SKIP')
pkgver() {
cd phosh
git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd phosh
git submodule init
git submodule update
}
build() {
# If we don't set `libexecdir` then meson will try and place the phosh bin in /lib/phosh and collide with the dir so we put it in /lib/phosh/phosh
arch-meson --libexecdir="/usr/lib/phosh" -D tests=false -D systemd=true phosh _build
meson compile -C _build
}
package() {
DESTDIR="${pkgdir}" meson install -C _build
}
|