blob: 6fd9bfc83ff751761c5a530b80cffe7a415c4d47 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
|
# $Id$
# Maintainer: Massimiliano Torromeo <massimiliano.torromeo@gmail.com>
pkgname=php-sqlsrv
pkgver=4.0.7
pkgrel=1
pkgdesc="Microsoft Drivers for PHP for SQL Server PHP 7 Linux"
arch=('i686' 'x86_64')
url="https://github.com/Microsoft/msphpsql/tree/PHP-7.0-Linux"
license=('MIT')
depends=('php' 'msodbcsql')
source=("https://github.com/Microsoft/msphpsql/archive/$pkgver-Linux/$pkgname-$pkgver.tar.gz")
sha256sums=('2feb763ee71642c49f3792e730928447b54c450999c522841f1c95cad46eb313')
backup=('etc/php/conf.d/sqlsrv.ini')
build() {
for ext in sqlsrv pdo_sqlsrv; do
cd "$srcdir"/msphpsql-$pkgver-Linux/source/$ext
phpize
./configure --prefix=/usr
make
done
}
package() {
for ext in sqlsrv pdo_sqlsrv; do
cd "$srcdir"/msphpsql-$pkgver-Linux/source/$ext
make INSTALL_ROOT="$pkgdir" install
done
cd "$pkgdir"
install -dm0755 etc/php/conf.d/
echo -e "extension=sqlsrv.so\nextension=pdo_sqlsrv.so" > etc/php/conf.d/sqlsrv.ini
install -Dm0644 "$srcdir"/msphpsql-$pkgver-Linux/LICENSE usr/share/licenses/$pkgname/LICENSE
}
|