blob: ed2f5802b2263b3082f5f193a0613ab94f79b426 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# Maintainer: Matt Harrison <matt@harrison.us.com>
# Maintained at: https://github.com/matt-h/aur-pkgbuilds or https://codeberg.org/matt/aur-pkgbuilds
pkgname=php-zstd
_pkgname=php-ext-zstd
pkgdesc='Zstd Extension for PHP'
pkgver=0.13.3
pkgrel=1
arch=('x86_64')
url='https://github.com/kjdev/php-ext-zstd'
license=('MIT')
depends=('php' 'zstd')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/kjdev/$_pkgname/archive/$pkgver.tar.gz"
'zstd.ini')
b2sums=('a01fff1f9533e281f94ad3ba8b6b44c4ea4cf7f23b6c28232e77c1a729a3f51f94f110229df131bfdb7de8d28a8c4a2f9123ba64dc9b965556d3169d452e12ff'
'00a1b0d80b05764c518768dd21370625887a85a5ce989ab708746fee731ab8e9b00f725531015abd99f953073b70efbfed9ae864054799c49810b126c0f4306e')
prepare() {
cd "$_pkgname-$pkgver"
phpize
}
build() {
cd "$_pkgname-$pkgver"
./configure --prefix=/usr --with-libzstd
make
}
check() {
cd "$_pkgname-$pkgver"
NO_INTERACTION=true make test
}
package() {
cd "$_pkgname-$pkgver"
make INSTALL_ROOT="$pkgdir/" install
install -D -m644 "${srcdir}/zstd.ini" "${pkgdir}/etc/php/conf.d/zstd.ini"
install -vDm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
}
|