PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40

# Maintainer: Michael Schubert <mschu.dev at gmail>
# Contributor: Abhishek Dasgupta <abhidg@gmail.com>
# Contributor: Damir Perisa <damir.perisa@bluewin.ch>
pkgname=phylip
pkgver=3.697
pkgrel=1
pkgdesc="A collection of programmes for evolutive genetics and inferring phylogenies"
arch=('i686' 'x86_64')
url="http://evolution.genetics.washington.edu/phylip.html"
source=("http://evolution.gs.washington.edu/phylip/download/phylip-$pkgver.tar.gz")
optdepends=('java-runtime')
license=('custom')
md5sums=('0e83d17fb4d668213603c86bc21d9012')

prepare() {
  cd "$srcdir"/$pkgname-$pkgver/src
  mv Makefile.unx Makefile
}

build() {
  cd "$srcdir"/$pkgname-$pkgver/src
  make all
}

package() {
  cd "$srcdir"/$pkgname-$pkgver/src
  make EXEDIR="$pkgdir"/usr/bin install

  # put fonts in the proper place.
  mkdir -p "$pkgdir"/usr/{lib,share/phylip}
  mv "$pkgdir"/usr/bin/*.so "$pkgdir"/usr/lib/
  mv "$pkgdir"/usr/bin/font* "$pkgdir"/usr/share/phylip/
  mv "$pkgdir"/usr/bin/{*.jar,*.unx} "$pkgdir"/usr/share/phylip/
  cp "$pkgdir"/usr/share/phylip/font1 "$pkgdir"/usr/share/phylip/fontfile

  # /usr/bin/factor is part of coreutils - factor -> factor_phylip
  mv "$pkgdir"/usr/bin/factor "$pkgdir"/usr/bin/factor_phylip

  install -Dm644 COPYRIGHT "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}