PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72

# Maintainer: Christopher Arndt <aur -at- chrisarndt -dot- de>
# Contributor: CrocoDuck <crocoduck dot oducks at gmail dot com>
# Contributor: Simon Thorpe <simon@hivetechnology.com.au>

pkgname=pianoteq-standard-trial-bin
pkgver=7.2.0
pkgrel=1
pkgdesc="Physical modelling piano instrument as a standalone program and VST2 and LV2 plugins. STANDARD trial version"
arch=('x86_64' 'armv7h' 'aarch64')
url="https://www.pianoteq.com/home"
license=('custom')
groups=('lv2-plugins' 'pro-audio' 'vst-plugins')
depends=('alsa-lib' 'libx11')
makedepends=('gendesk')
optdepends=('jack: JACK support for stand-alone application')
provides=("${pkgname%-*}")
conflicts=("${pkgname%-*}" 'pianoteq-standard-bin')
source=("file://pianoteq_linux_trial_v${pkgver//./}.7z"
        'https://www.pianoteq.com/images/logo/pianoteq_icon_128.png')
sha256sums=('97caf045c5ecb66acb6cf8fc2935e37f4e469cf9274814c7f636bd9e80ece15c'
            '94ee64cf6688a49d74f0bf70d811e7466abac103feeab17496a89f828afcc6d3')

prepare() {
  # Generate Desktop Entry:
  gendesk -f -n \
    --pkgname "${pkgname%-*}" \
    --pkgdesc "$pkgdesc" \
    --name='Pianoteq 7' \
    --exec="'Pianoteq 7'" \
    --categories 'Audio;Sequencer;Midi;AudioVideoEditing;Music;AudioVideo;'
}

package() {
  # Define architecture specific file directory:
  if [[ "$CARCH" == "x86_64" ]]; then
    archdir='x86-64bit'
  elif [[ "$CARCH" == "armv7h" ]]; then
    archdir='arm-32bit'
  elif [[ "$CARCH" == "aarch64" ]]; then
    archdir='arm-64bit'
  fi

  # Install program files:
  install -Dm 755 "$srcdir/Pianoteq 7/$archdir/Pianoteq 7" \
    "$pkgdir/usr/bin/Pianoteq 7"
  install -Dm 755 "$srcdir/Pianoteq 7/$archdir/Pianoteq 7.so" \
    "$pkgdir/usr/lib/vst/Pianoteq 7.so"
  cd "$srcdir/Pianoteq 7/$archdir/Pianoteq 7.lv2"
  for i in *; do
    install -D "$i" "$pkgdir/usr/lib/lv2/Pianoteq 7.lv2/$i"
  done
  cd $srcdir

  # Install desktop launcher:
  install -Dm 644 "$srcdir/pianoteq_icon_128.png" \
    "$pkgdir/usr/share/pixmaps/${pkgname%-*}.png"
  install -Dm 644 "$srcdir/${pkgname%-*}.desktop" \
    "$pkgdir/usr/share/applications/${pkgname%-*}.desktop"

  # Install the license:
  install -d "$pkgdir/usr/share/licenses/$pkgname"
  install -m 644 "Pianoteq 7"/*Licence* \
    "$pkgdir/usr/share/licenses/$pkgname/"

  # Install the Documentation:
  install -D "Pianoteq 7/README_LINUX.txt" \
    "$pkgdir/usr/share/doc/${pkgname}/README_LINUX.txt"
  cd "$srcdir/Pianoteq 7/Documentation"
  for i in *; do
    install -D "$i" "$pkgdir/usr/share/doc/${pkgname}/$i"
  done
}