PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43


# Maintainer: Andrea Feletto <andrea@andreafeletto.com>

pkgname=picomc-git
_pkgname=${pkgname%-*}
pkgver=0.4.5.r2.g597e670
pkgrel=1
pkgdesc='A tiny CLI Minecraft launcher'
arch=('any')
url='https://github.com/sammko/picomc'
license=('MIT')
depends=(
	'python>=3.7.0'
	'python-click>=7.0.0'
	'python-requests'
	'python-urllib3'
	'python-certifi'
	'python-tqdm'
	'python-coloredlogs'
	'python-colorama'
	'java-runtime'
)
provides=('picomc')
conflicts=('picomc')
source=("$pkgname::git+$url")
sha256sums=('SKIP')

pkgver() {
	cd "$srcdir/$pkgname"
	git describe --long | sed 's/^v//;s/-/.r/;s/-/./'
}

build() {
	cd "$srcdir/$pkgname"
	python setup.py build
}

package() {
	cd "$srcdir/$pkgname"
	python setup.py install --root="$pkgdir" --optimize=1 --skip-build
	install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$_pkgname"
	install -Dm644 README.md -t "$pkgdir/usr/share/doc/$_pkgname"
}