summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 7f74fd8232212d79feb881d8ccc1fb2d78a0226c (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>

pkgname=pidgin-privacy-please-git
pkgver=0.7.1.125.8c63bcf
pkgrel=1
pkgdesc='Pidgin plugin to stop spam'
url='https://github.com/cockroach/pidgin-privacy-please'
arch=('i686' 'x86_64')
license=('GPL3')
depends=('pidgin' 'libpurple')
makedepends=('git' 'intltool')
provides=('pidgin-privacy-please')
conflicts=('pidgin-privacy-please')
source=(${pkgname}::git+https://github.com/cockroach/pidgin-privacy-please)
sha512sums=('SKIP')

pkgver() {
  cd ${pkgname}
  printf "%s.%s.%s" \
    "$(git tag|sed -r 's|(release-)?(.*)|\2|g'|sort -Vr|head -n1)" \
    "$(git rev-list --count HEAD)" \
    "$(git rev-parse --short HEAD)"
}

prepare() {
	cd ${pkgname}
  sh autogen.sh
}

build() {
	cd ${pkgname}
  ./configure --prefix=/usr
	make
}

package() {
	cd ${pkgname}
  make DESTDIR="${pkgdir}" install
  install -Dm 644 ChangeLog README -t "${pkgdir}/usr/share/doc/${pkgname}"
}

# vim: ts=2 sw=2 et: