blob: 30737e8277643b86c41f61734754374fd5483de5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
# Maintainer: Daniel Bermond <dbermond@archlinux.org>
pkgname=pingo
pkgver=1.23.9
pkgrel=1
pkgdesc='Lossless and lossy image optimizer for PNG/JPEG/WebP/APNG (uses wine)'
arch=('any')
url='https://css-ig.net/pingo'
license=('LicenseRef-Unknown')
depends=('sh' 'wine')
makedepends=('git')
options=('!strip')
source=("pingo-win64-${pkgver}.zip"::'https://css-ig.net/bin/pingo-win64.zip'
'git+https://github.com/dbermond/shellutils.git')
noextract=("pingo-win64-${pkgver}.zip")
sha256sums=('e7d9b3ae70f40c85f9180e7e2bd4f39dfffe2b1e836e6cc61fc45ca9864ce65f'
'SKIP')
_useragent="User-Agent: Mozilla/5.0 (X11; Linux ${CARCH}) AppleWebKit/537.36 (KHTML, like Gecko) Chrome/126.0.6478.126 Safari/537.36"
DLAGENTS=("https::/usr/bin/curl \
-gqb '' -LC - --retry 3 --retry-delay 3 \
-H Upgrade-Insecure-Requests:\ 1 \
-H ${_useragent// /\\ } \
-H Referer:\ https://www.css-ig.net/pingo \
--compressed \
--output %o \
%u")
prepare() {
mkdir -p "${pkgname}-${pkgver}"
bsdtar -xf "pingo-win64-${pkgver}.zip" -C "${pkgname}-${pkgver}"
}
package() {
install -D -m755 shellutils/image/pingo -t "${pkgdir}/usr/bin"
install -D -m644 "${pkgname}-${pkgver}/pingo.exe" -t "${pkgdir}/usr/share/${pkgname}"
}
|