blob: a92326af96880b67fa02eb77f24dc83e012c868a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
|
# Maintainer: Ottatop <ottatop1227@gmail.com>
# Contributor: Yuuki Rika <yvvki@duck.com>
pkgname=pinnacle-comp-git
_pkgname=pinnacle
pkgver=0.1.0.r1547.1b165ca
pkgrel=2
pkgdesc="A Wayland compositor inspired by AwesomeWM (git version)"
arch=(x86_64 aarch64)
url="https://github.com/pinnacle-comp/${_pkgname}"
license=("GPL-3.0-or-later")
depends=(
wayland
libxkbcommon
libinput
mesa
seatd
systemd-libs
libdisplay-info
xorg-xwayland
protobuf
# Lua API
lua
lua-cqueues
lua-http
lua-protobuf
lua-posix
)
makedepends=(cargo git luarocks)
optdepends=(
"xdg-desktop-portal-gtk: a suggested XDG desktop portal"
"xdg-desktop-portal-wlr: for portal-based screencasting and screenshotting"
)
provides=(pinnacle-comp)
conflicts=(pinnacle-comp)
source=("git+$url.git")
sha256sums=("SKIP")
pkgver() {
cd "$_pkgname"
export RUSTUP_TOOLCHAIN=stable
echo "$(grep '^version =' Cargo.toml|head -n1|cut -d\" -f2).r$(git rev-list --count HEAD).$(git rev-parse --short HEAD)" | tr '-' '_'
}
prepare() {
cd "$_pkgname"
export RUSTUP_TOOLCHAIN=stable
cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}
build() {
cd "$_pkgname"
export RUSTUP_TOOLCHAIN=stable
cargo build --frozen --release
mkdir -p completions
./target/release/$_pkgname gen-completions --shell bash > completions/$_pkgname
./target/release/$_pkgname gen-completions --shell fish > completions/$_pkgname.fish
./target/release/$_pkgname gen-completions --shell zsh > completions/_$_pkgname
./target/release/$_pkgname gen-completions --shell elvish > completions/$_pkgname.elv
cd "api/lua"
luarocks --lua-version 5.4 make --pack-binary-rock --deps-mode none --no-manifest pinnacle-api-dev-1.rockspec
}
package() {
cd "$_pkgname"
install -Dm755 target/release/${_pkgname} -t "$pkgdir/usr/bin/"
install -Dm755 resources/${_pkgname}-session -t "$pkgdir/usr/bin/"
install -Dm644 resources/${_pkgname}.desktop -t "$pkgdir/usr/share/wayland-sessions/"
install -Dm644 resources/${_pkgname}-portals.conf -t "$pkgdir/usr/share/xdg-desktop-portal/"
install -Dm644 resources/${_pkgname}{.service,-shutdown.target} -t "$pkgdir/usr/lib/systemd/user/"
install -Dm644 completions/$_pkgname -t "$pkgdir/usr/share/bash-completion/completions/"
install -Dm644 completions/$_pkgname.fish -t "$pkgdir/usr/share/fish/vendor_completions.d/"
install -Dm644 completions/_$_pkgname -t "$pkgdir/usr/share/zsh/site-functions/"
install -Dm644 completions/$_pkgname.elv -t "$pkgdir/usr/share/elvish/lib/"
cd "$srcdir/$_pkgname/api/protobuf"
for proto in $(find . -type f -name *.proto); do
install -Dm644 $proto "$pkgdir/usr/share/$_pkgname/protobuf/${proto#\./}"
done
cd "$srcdir/$_pkgname/snowcap/api/protobuf"
for proto in $(find . -type f -name *.proto); do
install -Dm644 $proto "$pkgdir/usr/share/$_pkgname/snowcap/protobuf/${proto#\./}"
done
cd "$srcdir/$_pkgname/api/lua"
luarocks --lua-version 5.4 --tree "$pkgdir/usr/" install --deps-mode none --no-manifest *.rock
}
|