summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 7b76ee30e622c5973945d40674e834c241820fd9 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
pkgname=pipewire-git
pkgver=0.2.3.17.g10ce1a02
pkgrel=1
pkgdesc="Multimedia processing graphs. (GIT version)"
arch=('x86_64')
url='https://pipewire.org'
license=('LGPL')
depends=('ffmpeg'
         'v4l-utils'
         'sbc'
         )
makedepends=('graphviz'
             'doxygen'
             'xmltoman'
             'git'
             'meson'
             'valgrind'
             )
conflicts=('pipewire')
provides=('pipewire')
source=('git+https://github.com/PipeWire/pipewire.git')
sha256sums=('SKIP')
backup=('etc/pipewire/pipewire.conf')

pkgver() {
  cd pipewire
  echo "$(git describe --long --tags | tr - .)"
}

prepare() {
  mkdir -p build

  # Reduce docs size
  printf '%s\n' >> pipewire/doc/Doxyfile.in \
    HAVE_DOT=yes DOT_IMAGE_FORMAT=svg INTERACTIVE_SVG=yes

  cd build

  arch-meson ../pipewire \
    -D docs=true \
    -D man=true \
    -D gstreamer=disabled

}

build() {
  ninja -C build
}

package() {
  DESTDIR="${pkgdir}" ninja -C build install
}