blob: c149dbef510a792251e46c002b29d3216776db63 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
pkgname=pipgrip
pkgver=0.10.13
pkgrel=2
pkgdesc="Lightweight pip dependency resolver with deptree preview functionality based on the PubGrub algorithm"
arch=('any')
url="https://github.com/ddelange/pipgrip"
license=('BSD 3-Clause')
depends=(
'python-anytree'
'python-click'
'python-packaging'
'python-pip'
'python-setuptools'
'python-wheel'
)
makedepends=(
'python-build'
'python-installer'
'python-setuptools-scm'
)
source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/$pkgver.tar.gz")
sha256sums=('5771986f78898265845b2d920b0689f80e45c62c1fe4c5b3d2a3d47f23f7a46d')
prepare() {
cd "$pkgname-$pkgver"
# Relax requirements
sed -i 's/setuptools_scm<7/setuptools_scm/g' setup.py
}
build() {
cd "$pkgname-$pkgver"
export SETUPTOOLS_SCM_PRETEND_VERSION=$pkgver
python -m build --wheel --no-isolation
}
package() {
cd "$pkgname-$pkgver"
python -m installer --destdir="$pkgdir" dist/*.whl
install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
}
|