blob: 748ad6d4b95f611de34d11e8fbaff83416af1249 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: Alex Wilson <alex at cooperi dot net>
pkgname=pivy
pkgver=0.9.0
pkgrel=2
pkgdesc="Tools for using PIV smartcards/Yubikeys with ssh-agent and disk encryption"
url="https://github.com/arekinath/pivy"
license=('MPL2')
source=(
"zfs-pivy.hook"
"zfs-pivy.install"
"https://github.com/arekinath/pivy/releases/download/v$pkgver/pivy-$pkgver-src.tar.gz"
"https://github.com/arekinath/mini-pcsc/archive/v0.2.0.tar.gz")
arch=(x86 x86_64)
depends=(libbsd pcsclite libedit)
optdepends=('cryptsetup: LUKS encrypted disk support (pivy-luks)'
'zfs-utils: ZFS encrypted pool/fs support (pivy-zfs)'
'pam: PAM plugin (pam_pivy.so)')
makedepends=(pkgconf cryptsetup zfs-utils json-c pam)
sha256sums=('7925467b71227ae835cc5bf5ebf0b74ea6d740738af5d13be05e0416a78f8acc'
'44b5a004a06ffe214df2810bb2d58a3ecb2bdcf1c892411a8d574afac935f678'
'a2e4574142e7112cf2434566a51697ebabe28916d42ab0729c54dfea6f7c420e'
'a2c23b7b9e3dc976b54627a08da68b76fd6194ba45d211959dedf4700879379e')
# Don't use --as-needed when linking, will break pam_pivy
LDFLAGS+=" -Wl,--no-as-needed"
build() {
cd "$pkgname-$pkgver"
make prefix=/usr USE_ZFS=yes USE_LUKS=yes USE_PAM=yes
cd "../mini-pcsc-0.2.0"
make
}
package() {
cd "$pkgname-$pkgver"
make prefix=/usr DESTDIR="$pkgdir/" USE_ZFS=yes USE_LUKS=yes USE_PAM=yes install
cd "../mini-pcsc-0.2.0"
install -o root -g root -m 0755 -d "${pkgdir}/usr/lib"
install -o root -g root -m 0755 libminipcsc.so "${pkgdir}/usr/lib/libminipcsc.so"
cd "$srcdir"
hookdir="${pkgdir}/usr/lib/initcpio/hooks"
hookinsdir="${pkgdir}/usr/lib/initcpio/install"
install -o root -g root -m 0755 -d "$hookdir"
install -o root -g root -m 0644 zfs-pivy.hook "${hookdir}/zfs-pivy"
install -o root -g root -m 0755 -d "$hookinsdir"
install -o root -g root -m 0644 zfs-pivy.install "${hookinsdir}/zfs-pivy"
}
|